Re: [xml-dev] XSLT question on transitive closures

[David Carlisle <davidc@nag.co.uk>]

> Transitive closure is intrinsically a higher-order function,

But guessing (since it's Rick) that this is a schematron question
which means that one's generating a stylesheet dynamically anyway,
There is thus the possibility to generate, given a function implementing
an xpath expression, a specific closure function.

As below where the form of the functions c() c2() and c3() are all
identical, but they can't be parameterised by the function to call, so
each have a static reference to f() f2()and f3() respectively.

> The other thing that's needed is the ability to check for cycles. Simply
> blowing the stack or looping isn't good enough.

the code below just uses the Xpath2 except operator so that you only
recurse on new nodes, hopefully that's efficient enough for this
purpose.


> I think it would be nice to do it properly based on FXSL higher-order

True (but I'll leave that for Dimitre:-)

David

$ saxon8 -it main closure.xsl 
<?xml version="1.0" encoding="UTF-8"?>

=== . on a  ====
a
===========

=== grandchild on a ====
a c f kkk hhh c2
===========


=== aunt on kkk ====
d kkk c2 b2
===========









<xsl:stylesheet version="2.0" 
		xmlns:xsl="http://www.w3.org/1999/XSL/Transform";
		xmlns:c="data:,c"
		exclude-result-prefixes="c"
		>
  
<xsl:function name="c:c" as="node()*">
  <xsl:param name="nodes" as="node()*"/>
  <xsl:variable name="n2" select="$nodes/(c:f(.))"/>
  <xsl:sequence select="$nodes | $n2 |($n2 except $nodes)/c:c(.)"/>
</xsl:function>

<xsl:function name="c:f" as="node()*">
  <xsl:param name="node" as="node()"/>
  <xsl:sequence select="$node/."/>
</xsl:function>

<xsl:function name="c:c2" as="node()*">
  <xsl:param name="nodes" as="node()*"/>
  <xsl:variable name="n2" select="$nodes/(c:f2(.))"/>
  <xsl:sequence select="$nodes | $n2 |($n2 except $nodes)/c:c2(.)"/>
</xsl:function>

<xsl:function name="c:f2" as="node()*">
  <xsl:param name="node" as="node()"/>
  <xsl:sequence select="$node/*/*"/>
</xsl:function>



<xsl:function name="c:c3" as="node()*">
  <xsl:param name="nodes" as="node()*"/>
  <xsl:variable name="n2" select="$nodes/(c:f3(.))"/>
  <xsl:sequence select="$nodes | $n2 |($n2 except $nodes)/c:c3(.)"/>
</xsl:function>

<xsl:function name="c:f3" as="node()*">
  <xsl:param name="node" as="node()"/>
  <xsl:sequence select="$node/../../* except $node/parent::*"/>
</xsl:function>

<xsl:template name="main">

=== . on a  ====
<xsl:sequence select="c:c($doc/a)/name()"/>
===========

=== grandchild on a ====
<xsl:sequence select="c:c2($doc/a)/name()"/>
===========


=== aunt on kkk ====
<xsl:sequence select="c:c3($doc//kkk)/name()"/>
===========



</xsl:template>
	    


<xsl:variable name="doc">
  <a>
    <b>
      <c>
	<d/>
	<e>
	  <f/>
	  <kkk/>
	  <hhh>
	    <ll/>
	  </hhh>
	</e>
      </c>
      <c2/>
    </b>
    <b2/>
  </a>
</xsl:variable>

</xsl:stylesheet>

________________________________________________________________________
The Numerical Algorithms Group Ltd is a company registered in England
and Wales with company number 1249803. The registered office is:
Wilkinson House, Jordan Hill Road, Oxford OX2 8DR, United Kingdom.

This e-mail has been scanned for all viruses by Star. The service is
powered by MessageLabs. 
________________________________________________________________________